The Coordinate Manipulation Commands
The commands in this section are primarily used for moving
some or all of the atoms. There is a wide range of commands and options.
All of the commands may be used on either the main coordinate set, or
the comparison set. Some commands require both sets of coordinates.
* Menu:
* Syntax:: Syntax of the coordinate manipulations commands
* Simple:: Descriptions of the simple commands
* Function:: Descriptions of the remaining commands
* Substitutions:: Description and usage of substitution values
Syntax of Coordinate Manipulation commands
[SYNTAX COORdinate manipulation]
COORdinates { INITialize } [COMP] [atom-selection]
{ COPY } [WEIGhting_array]
{ SWAP } [IMAGes]
{ AVERage [ FACT real ] }
{ SCALe [ FACT real ] }
{ MASS_weighting }
{ ADD }
{ SET vector-spec }
{ TRANslate vector-spec }
{ ROTAte vector-spec {PHI real} }
{ {MATRix} }
{ ORIEnt [MASS] [RMS] [NOROtation] }
{ RMS [MASS] }
{ DIFFerence }
{ FORCe [MASS] }
{ SHAKe [MASS] }
{ DRAW draw-spec }
{ DISTance distance-spec [DIFF] }
{ MINDist distance-spec }
{ READ io-specification }
{ WRITe io-specification }
{ PRINt io-specification }
{ RGYR [MASS] [FACT <real>] }
{ LSQP [MASS] [VERBose] }
{ OPERate image_name }
{ STATistics [MASS] }
{ VOLUme {SPACe integer} }
{ }
{ DUPLicate { 2X(atom-selection) } }
{ { PREVious } }
COORdinates HBONd 2X(atom-selection) [CUT <real>] [CUTA <real>] [IUNIt <int>]
[BRIDge <resnam>]
[FIRSt int] [NUNIts int] [NSKIp int] [BEGIn int] [STOP int]
COORdinates DYNAmics [COMParison] [PAX] [atom-selection] [NOPRint]
[FIRSt int] [NUNIts int] [NSKIp int] [BEGIn int] [STOP int]
COORdinates PAXAnalysis [COMParison] [atom-selection] [NOPRint]
[FIRSt int] [NUNIts int] [NSKIp int] [BEGIn int] [STOP int] [SAVE]
COORdinates SEARch { search-spec } { [NOPRint] [NOSAve] }
{ INVErt } { PRINt [UNIT int] [SAVE] }
{ KEEP xvalue yvalue zvalue } { SHAPe name [CHARges] }
{ EXTEnd RBUFf real }
search-spec :: [atom-selection] [COMP] [IMAGe] [operation-spec]
[XMIN real] [XMAX real] [XGRId integer]
[YMIN real] [YMAX real] [YGRId integer]
[ZMIN real] [ZMAX real] [ZGRId integer]
operation-spec ::= { } { [VACUum] } { [RESEt] }
{ [RCUT real] } { FILLed } { AND }
{ [RBUFf real] } { HOLES } { OR }
{ XOR }
{ ADD }
COORdinates SURFace [atom-selection] [WEIGhting] { CONTact-area }
[ACCUracy real] { ACCEssible-area }
[RPRObe real]
COORdinates CONVert-from/to-unit-cell [ from | to ] -
[atom-selection] [COMP] [IMAGe] -
a b c alpha beta gamma
[ from | to ] ::= [ FRACtional | SYMMetric | ALIGned ]
COORdinates AXIS atom-selection [atom-selection] [MASS] [COMP] [IMAGEs]
COORdinates COVAriance -
[FIRStunit int] [NUNIt int] [BEGIn int] [SKIP int] [STOP int]
2x(atom_selection) [UNIT_for_output int] [DISTance_matrix]
[RESIdue_average_nsets integer]
COORdinates PUCKer SEGId segid RESId resid1 TO resid2
COORdinates HELIx atom-selection [atom-selection]
COORdinate ANALysis {SOLVent} {WATer} SPEC <selection-syntax> FINIish -
{XREF <real> YREF <real> ZREF <real>} - !syntax to set-up arbitrary
!analysis point
{SITE <selection-syntax>} - !syntax to set-up solute anaylsis site
NFIRst <int> NSTEp <int> NSKIp <int> - !syntax for reading trajectories
NCORs <int> RSPIn <real> RSPOut <real> - !correlation function set-up
DTCOordinates <real> DTVElocity <real> - !timestep information
RDSP <real> DR <real> RRSP <real> MGN <int> - !more analysis info
IMSD IVAC IGDISt ISDISt IKIRkg- !set-up for logical compute flags
IFMIn XBOX <real> YBOX <real> ZBOX <real> - !PBC info for analysis
IFDBF RCUT <real> ZP0 <real> NZP <int> !analysis info for DBF analysis
atom-selection:== (see *note select:(select.doc).)
distance-spec::=
{ WEIGhting vector-spec atom-selection }
{ }
{ [UNIT int] [CUT real] [ENERGy [CLOSe]] 2X(atom-selection) - }
{ [Nonbonds] } { [NO14exclusions] } { [NOEXclusions] } -
{ NONOnbonds } { 14EXclusions } { EXCLusions }
[TRIAngle] [ HISTogram HMIN real HMAX real HNUM integer -
[HSAVe] [HPRInt] [HNORm real] [HDENsity real] ]
vector-spec::= { [XDIR real] [YDIR real] [ZDIR real] } [DISTance real]
[XCEN real] [YCEN real] [ZCEN real] [FACTor real]
{ AXIS }
draw-spec::= [DFACt real] [NOMO] UNIT integer
io-specification:== (see *note io:(io.doc).)
Descriptions of the simple coordinate manipulation commands
All of these commands allow either the main coordinate set (default),
or the comparison set (COMP keyword) to be modified. The other coordinate
set is only changed by the SWAP command and the ORIEnt RMS command when
the specified atoms are not centered about the origin.
Each of these commands may also operate on a subset of the full
atom space. The selection specification should be at the end of the command.
The default atom selection includes all atoms.
If the IMAGes keyword is specified, then the operation will be
performed on the image atoms as well (if images are present).
------------------------------------------------------------------------------
1) The INITialize command
The INITialize command returns the coordinate values of the
specified atoms to their start up values (9999.0). The main use of
this command is in connection with the IC BUILD command, which may
only find coordinates for atoms with the initial value.
------------------------------------------------------------------------------
2) The COPY command
The COPY command will copy the coordinate values into the
specified set FROM the other coordinate set.
------------------------------------------------------------------------------
3) The SWAP command
The SWAP command will cause the coordinate values of the
specified atoms to be swapped with the comparison set.
------------------------------------------------------------------------------
4) the AVERage command
The AVERage command will generate a new coordinate set at a
point along the displacement vector between the present coordinate set
and the other set. The FACTor value determines the relative step along
this vector. Its default value is 0.5 (a true average). A FACTor value of
1.0 is equivalent to the copy command. Negative or greater than unit
positive values are also allowed.
------------------------------------------------------------------------------
5) The SCALe command
The SCALe command will cause the coordinate values for all
selected values to be scaled by a required scale factor. This option
is designed to work with coordinate displacement vectors. A scale
factor of zero will set the selected coordinate values to zero.
This option may also be useful in plotting.
------------------------------------------------------------------------------
6) The MASS_weighting command
The MASS_weighting command will cause all selected coordinates
to be scaled by the MASS of each atom. If the WEIGht option is specified,
the weighting array will be scaled.
------------------------------------------------------------------------------
7) The ADD command
The add command will add the main and the comparison
coordinate values and store the results in the selected coordinate set.
As with other commands, only selected atoms will be modified. If
an atom in either set is undefined, then the sum will also be undefined.
This option is designed for use in cases where one or both coordinate
sets contain coordinate displacement vectors.
------------------------------------------------------------------------------
8) The SET command
The SET command will set all coordinate values of selected
atoms to a specified value determined by the vector specified. This is
a simple manner in which to zero a coordinate set with the command;
COOR SET XDIR 1.0 DIST 0.0
Note, the XDIR keyword value was included so that the vector has a nonzero
norm (required for all vector specifications).
------------------------------------------------------------------------------
9) The TRANslate command
The TRANslate command will cause the coordinate values of
the specified atoms to be translated. The translation step may be
specified by either X,Y, and Z displacements, or by a distance along
the specified vector. When no distance is specified, The XDIR,YDIR, and
ZDIR values will be the step vector. If the AXIS keyword is used, then
the translation will be along the axis defined by the previous COOR AXIS
command. For this option, a distance may be specified, but if it isn't,
then the translation distance will be the COOR AXIS vector length
------------------------------------------------------------------------------
10) The ROTAte command
The ROTAte command will cause the specified atoms to be rotated
about the specified axis vector through the specified center. The vector
need not be normalized, but it must have a non zero length. If the AXIS
keyword is used, then the axis and center information from the last
COORdinates AXIS command will be used. The PHI value gives the amount
of rotation about this axis in degrees.
(NOTE: this command uses a left handed sense, not the right hand rule...)
Only the atoms specified will be rotated. If the MATRix keyword is used
the rotation will be made using an explicit rotation matrix, input in
free format on the three following lines (3 real numbers /line):
U(1,1) U(1,2) U(1,3)
U(2,1) U(2,2) U(2,3)
U(3,1) U(3,2) U(3,3)
------------------------------------------------------------------------------
11) The ORIEnt command
The ORIEnt command will modify the coordinate values of ALL of
the atoms. The select set of atoms is first centered about the origin,
and then rotated to either align with the axis, or the other coordinate set.
The RMS keyword will use the other coordinate set as a rotation reference.
The MASS keyword cause a mass weighting to be done. This will
align the specified atoms along their moments of inertia. When the RMS
keyword is not used, then the structure is rotated so that its principle
geometric axis coincides with the X-axis and the next largest coincides
with the Y-axis. This command is primarily used for preparing a
structure for graphics and viewing. It can also be used for finding
RMS differences, and in conjunction with the vibrational analysis.
The NOROtation keyword will suppress rotations. In this case,
only one coordinate set will be modified.
------------------------------------------------------------------------------
12) The RMS command
The RMS command will compute the RMS or mass weighted RMS
coordinate differences between the selected set of atoms just as they
lie. This differences from the COOR ORIENT RMS command in that no coordinate
modifications are made and no translation is done.
------------------------------------------------------------------------------
13) The DIFF command
The DIFF command will compute the differences between the main
and comparison set (or the reverse) and store this difference in the
modified coordinate set. Undefined or unselected atoms result in a zero.
------------------------------------------------------------------------------
14) The FORCe command
The FORCe command will copy the current forces (DX,DY,DZ)
of the selected atoms to the specified coordinate set. Atoms not selected
are given a value of zero. If the MASS keyword is specified, then the
forces will be divided by the mass. This would correspond to an
acceleration in dynamics.
------------------------------------------------------------------------------
15) The SHAKe command
This command will SHAKE the selected coordinate set with respect
to the other (as a reference). A mass weighting may be used. Any atoms
that are not selected are considered to be fixed (infinite mass).
In order to use this command, the SHAKe command must first be invoked
which sets up the shake constraints.
Descriptions of the remaining corman commands
See the descriptions of the simple commands for some background
information on these commands.
------------------------------------------------------------------------------
1) The DISTance command
The COOR DIST command will either find distances between atoms
or the distances of atoms from a fixed point in space (WEIGh option).
This command can find distances within a single coordinate set, or
find distances between atoms in two coordinate sets (DIFF option).
The DISTance command can find all atom distances between two
atom selections. A unit number may be specified (default=6) and a
cutoff distance may be included as well (default=8999.0). If no selection
is specified, all atoms will be included! The delimiter ENDselection
must separate the two sets of atom selections. The van der Waal energy
may be requested with the "ENERgy" keyword, and if this option is used,
the list of pairs with a positive van der Waal energy may be selected
with the "CLOSe" keyword (i.e. only close contacts will be listed).
The NEAR option will list the nearest atom in the second atom selection
to the atoms in the first selection.
The COOR DISTance command doesn't gives distances between
excluded atoms unless the "EXCLusions" keyword is specified. This make
it much easier to search for bad contacts. Likewise, 1-4 interactions and
other interactions may be requested or omitted.
The command;
COOR DISTance ENERgy CLOSe CUT 5.0 SELE ALL END SELE ALL END -
14EXclusions NONBonds
will list all atom pairs that have a positive van der Waal energy.
The command;
COOR DISTance ENERGY CUT 5.0 NONONbonds NOEXclusions 14EXCLusions -
SELE ALL END SELE ALL END
will list all 1-4 interactions and energies (and nothing else).
The command;
COOR DISTance ENERgy CUT 4.5 SELE RESID 23 END SELE ALL END
will list all contacts less than 4.5A that residue 23 has with the rest of
the system without considering 1-4 interactions or excluded pairs.
The 1-4 vdw terms, E14FAC, and EPS values other than 1.0 are recognized.
The WEIGht option puts the distance of all selected atoms from some
specified point. If no point is specified, then the origin is used. This
is most useful in computing magnitudes of forces or coordinate differences.
For example, the sequence;
ENERGY ...
COOR FORCE COMP ! copy forces to the comparison coordinates
COOR DIST WEIGH COMP ! put magnitudes in the weighting array.
PRINT COOR COMP SELE PROP 1 .GT. 5.0 END ! print atoms with large
forces. Note that all operations were done on the comparison set.
The DIFF keyword causes the selection to work on different coordinate
sets, where the first selection corresponds to the set specified (MAIN or COMP),
and the second atom selection uses the other coordinate set.
The HISTogram option allows a histogram of distances to be produced.
With the histogram, the HMIN and HMAX (the range of the histogram in angstroms)
and the HNUM (the number of bins) must be specified. The HSAVe keyword causes
the histogram values to be saved for subsequent COOR DIST commands. In a loop,
this allows g(r) to be calculated from a dynamics trajectory. The HPRInt
option will cause the final histogram values to be printed. The HNORm value
will be used to normalize the histogram before printing (divide by HNORm).
The histogram will also be scaled by the reciprocal of the distance squared
(to get normalized g(r) plots). Three columns of numbers are output;
(1) the bin midpoint distance, (2) the normalized g(r), and (3) the total
number of pairs within the bin divided by the HNORM value.
A PRNLEV less than 5 will suppress the listing of distance pairs.
Example of use to get a distance distribution plot:
update imgfrq 20 cutim 20.0
traj ....
prnlev 4
set 1 1
label loop
traj read
coor dist image sele segid main .and. type OH2 end sele type OH2 end -
cut 10.5 HIST HMIN 0.0 HMAX 10.0 HNUM 50 HSAVE
incr 1 by 1
if 1 .lt. 1000.5 goto loop
coor dist sele none end sele none end -
cut 10.5 HIST HMIN 0.0 HMAX 10.0 HNUM 50 HNORM 1000.0 HPRINT
------------------------------------------------------------------------------
2) The RGYR command
The RGYR command can compute the Radius of GYRation, center-of-mass
and total mass of the specified atoms. By default the RGYR, uses a unit
weighting factor providing the rms distance from the center of geometry.
The current keywords are:
MASS use mass weighting (otherwise use unit weight per selected atom)
WEIG use a weight array (WMAIN or WCOMP) for the weighting
FACT constant to be subtracted from each weight
The weight arrays can be filled, by using COOR or SCALAR commands,
before invoking the RGYR routine. In this way almost any RGYR can be computed.
------------------------------------------------------------------------------
3) The LSQP command
The LSQP command computes the least-squares-plane through the
selected atoms. Weighting can be done by the atom masses [MASS], by
the weighting array [WEIG], or not at all (default). Output is the
equation for the plane, the sum-of-squared distances (weighted) from
the plane (SSQ), and the center-of-mass of the selected atoms.
The keyword VERBose causes some additional output, most useful of
which is the distance from the plane for each atom.
------------------------------------------------------------------------------
4) The OPERate command.
The OPERate command processes the selected coordinates through
the image transformation specified by name. This command may only be
used if an image file has been read.
------------------------------------------------------------------------------
5) The MINDistance command.
The MINDistance command computes the minimum distance between
selected coordinates. Usually this command is executed with a double
selection. If only one selection is given, then it will give the minimum
distance of the selected coordinates between the MAIN and COMPARISON set.
------------------------------------------------------------------------------
6) The STATistics command
The STATistics command will print some simple statistics
regarding the selected atoms. The values XMIN,YMAX,XAVE,YMIN,YMAX,YAVE,
ZMIN,ZMAX,ZAVE,WMIN,WMAX,WAVE are set when this command is executed. These
variable values may then be used un subsequent commands with the "?" symbol.
For example, the command sequence may be used to shift a structure so that
a single atom is in the X-Y plane (e.g. shift in the z-direction);
COOR STATistics SELE desired-atom END
COOR TRANS ZDIR ?ZAVE FACT -1.0
The MASS option will place the average values at the center of mass.
------------------------------------------------------------------------------
7) The AXIS command.
The AXIS command generates a vector and saves it for subsequent use
for either command parsing, or for use as input in the COOR SET, COOR ROTAte,
COOR TRANslate, or COOR DISTance WEIGhting commands by using the AXIS keyword.
There are two modes for the AXIS command. With a single atom selection, the
stored vector is the defined from the origin to the center of geometry/mass
of all selected atoms. With two atom selections, the vector spans from the
center of the first set of selected atoms to the center of the second.
The MASS keyword invokes the usage of the center of mass.
The AXIS command sets the variables XAXIs, YAXIs, ZAXIs, RAXIs, XCEN, YCEN,
and ZCEN, which may be accessed with the "?" symbol. These values define
the actual vector, the length of the vector, and the center of the vector
(midpoint). For example, to use the distance between two atoms as a
criterion to terminating a run, the following command sequence could be used;
SET 1 10.0
COOR AXIS SELE first-atom END SELE second-atom END
IF 1 GT ?RAXIs STOP
For another example, to rotate the chi-1 torsion of a
specified residue BY 30 degrees, the command sequence would be appropriate;
DEFINE BACK SELE TYPE O .OR. TYPE N .OR. TYPE H .OR. TYPE CA .OR. TYPE C END
COOR AXIS SELE ATOM MAIN 23 CA END SELE MAIN 23 CB END
COOR ROTATE AXIS PHI 30.0 SELE RESID 23 .AND. .NOT. BACK END
------------------------------------------------------------------------------
8) The DUPLicate command.
The DUPLicate command copies coordinates between atoms within
a structure. The coordinates are copied FROM the first selection TO the
second selection. If the selections overlap, watch out!. The matching is
done by number within the selected coordinate sets. If the two selection
have a different number of atoms, a warning will be issued, and the smaller
number will be used. For example, if one needs to compute the relative
orientation between two alpha helicies, the following input might be used;
COOR COPY COMP
COOR DUPL COMP SELE backbone of first END SELE backbone of second END
COOR ORIE RMS MASS COMP SELE backbone of second END
This will give the RMS shift between these helicies as well as the
coordinate transformation required to map one into the other.
The PREVious option may be used with a single atom selection.
This assigns the coordinate position of selected atoms to the value
of the previous atom (by number). This has been used with the command;
COOR DUPLicate PREVious SELE TYPE H* END
to assign hydrogen atom positions to that of the associated heavy atom.
The COMP keyword causes only the comparison coordinates to be used and
modified. Otherwise, the entire operation involves only the main coordinates.
------------------------------------------------------------------------------
9) The DYNAmics command
The COOR DYNAmics command will read a (set of) dynamics trajectory
files and compute the average coordinates (stored in the selected
coordinate set) and the isotropic fluctuations (stored in the weighting
array). The first unit number (FIRSt)(default 51), number of units (NUNIts)
(default 1), frequency of accepted coordinate sets (NSKIp)(default 1),
starting set (BEGIn)(default first set), last set (STOP)(default last set),
may be specified. Option values are not remembered with subsequent
COOR DYNA commands. The NOPRint supresses much of the output.
The PAX command causes the Principal AXis of the motion of each atom
to be computed and save. The print out gives the direction and magnitude
of the fluctuation as well as the anisotropies. The PAX data is saved for
a subsequent COOR PAXAnal command if further analysis is desired.
------------------------------------------------------------------------------
10) the PAXAnal command
The COOR PAXAnal command computes additional data regarding the
Pricipal AXis data (computed by the most recent COOR DYNA PAX command).
The trajectory must be reopened and reread, or a different trajectory
may be substituted. This command prints data for each selected atom and
averages over the selected atoms. The printout includes the skew and
kurtosis, anisotropies, as well as all of the low moments of the motion.
The SAVE option causes the PAX data structure (from the COOR DYNA PAX command)
to be saved (for subsequent COOR PAXA commands).
------------------------------------------------------------------------------
11) the SEARch command
COORdinates SEARch { search-spec } { PRINt [UNIT int] [SAVE] }
{ INVErt } { [NOPRint] [NOSAve] }
{ KEEP xvalue yvalue zvalue }
{ EXTEnd RBUFf real }
{ SHAPE name }
search-spec :: [atom-selection] [COMP] [IMAGe] [operation-spec]
XMIN real XMAX real XGRId integer
YMIN real YMAX real YGRId integer
ZMIN real ZMAX real ZGRId integer
operation-spec ::= { } { [VACUum] } { [RESEt] }
{ [RCUT real] } { FILLed } { AND }
{ [RBUFf real] } { HOLES } { OR }
{ XOR }
{ NAND }
{ ADD }
The SEARch command generates and/or manipulates a grid of small volume
elements.
The SEARch command will search through a set of grid points
for vacuum space points (i.e. points outside the van der Waal radius of
any atom). In the default mode (NOPRint), only the relative volume of filled
and vacuum points are printed concerning the selected atoms.
The grid specifiers must be input (min, max, and grid) for each dimension.
(grid implies number of grid points. Hence
XMIN -13.0 XMAX 13.0 XGRID 52.0
implies a half Angstorm sampling along the x direction)
The FILLed option will cause non-vacuum points to be listed or plotted.
The PRINt option will cause all found grid points to be listed on the
output unit specified (default 6). The plot option will make a line
printer plot of all found grid points. For this option, a plot order
may be specified (XYZ,XZY,YXZ,...), Where the first index is the horizontal
(maximum grid 64), the second is the vertical (no maximum), and the last
is obtained by paging (no maximum).
For this command, the atom sizes are taken from the weighting
array. To get van der Waal radii into the weighting array, the command;
SCALar WMAIn = RADIus
may be used. If a hole big enough to stuff a water into is to be found,
then the command sequence;
SCALar WMAIn = RADIus
SCALAR WMAIN ADD 1.6
SCALAR WMAIN MULT 0.85
would be probably the best to use.
If the RCUT or RBUFf value is set to a nonzero value, then the accessible
volume command is enabled. When RCUT is set, this is the maximum radius.
When RBUFf is set, then the maximum radius is the weighting array plus the
RBUFf value. The weighting array is returned with the fraction of free volume
in the shell from the atom radius to the maximum radius.
If the HOLEs keyword is set, only the grid points not connected to the
first point (point in the negative corner of the box) are considered.
In this way, the volume of just the holes can be analyzed and saved.
The "ADD" option for the COOR SEARCH command has been added to allow
the calculation of partial occupancy factors. This allow holes in proteins
to be analyzed for flexibility and variability.
It is possilbe to use multiple COOR SEARch commands and to use boolean
operations to combine the results. For example, the script sequence;
COORdinates SEARch IMAGe -
XMIN -10.0 XMAX 10.0 XGRId 20 -
YMIN -10.0 YMAX 10.0 YGRId 20 -
ZMIN -10.0 ZMAX 10.0 ZGRId 20 -
NOPRINT VACUUM SAVE
....
SCALAR WMAIN ...
....
COORdinates SEARch IMAGe -
XMIN -10.0 XMAX 10.0 XGRId 20 -
YMIN -10.0 YMAX 10.0 YGRId 20 -
ZMIN -10.0 ZMAX 10.0 ZGRId 20 -
AND PRINT UNIT 22 RBUFF 2.0 FILLED
Note, the results of these two commands are computed and the
intersection (AND) is printed. The first command needs a "SAVE" in order
for the results to be saved. Also, the grids must exactly match
(same number of grid points in all dimensions) for this operation to work.
The COOR SEARch command allocates space, if needed, and frees the space unless
the SAVE option is used. Thus, if four COOR SEARch commands are needed for a
single computation, the first three must have the SAVE option. The only way
to free the space allocated by the COOR SEARch SAVE command is to run another
COOR SEARch command.
------------------------------------------------------------------------------
12) the VOLUme command
The VOLUme command will compute the volume of a selected set of
atoms. Its operation is the same as that of the SEARch command, except
that only the volume is printed and the degree of exposure for each atom
is returned in the weighting array. The SCALAR storage arrays must be filled
before using this command. The first storage array [1] must contain
the radii of each atom (RMIN) and the second storage array must contain the
outer probe distance (RMAX) for each atom. The free volume within the RMIN
to RMAX range and not within RMIN of any other atom will be returned in the
weighting array as a ratio of the maximum possible value. For example a
completely exposed atom will return a value of 1.0 and an atom in the interior
of a protein would return a value of 0.0. The HOLEs keyword feature
causes holes within the selected atoms to be filled before computing
the total volume and the accesible volume.
SPACE is a maximum number of cubic pixels
i.e. SPACE = x_points * y_points * z_points
Larger SPACE value results in more accurate calculation but it takes more
memory an computer time. Number of points in x,y and z directions are
determined according to the formula:
factor = ( SPACE / (a*b*c) ) ** (1/3)
x_points = factor*a
y_points = factor*b
z_points = factor*c
where a, b and c are dimensions of the smallest rectangular box
enclosing the molecule.
------------------------------------------------------------------------------
13) The SURFace command
The COOR SURFace command computes the Lee and Richards surface for
selected atoms and stores the result in the appropriate weighting
array. If the "WEIGhting" keyword is used, the radii are obtained from
the weighting array (and then written over), otherwise the radii are
obtained from the parameter file values. The radius of the probe may
be specified (default 1.6) and the accuracy may be specified (default 0.05).
Either ACCEssible surface (default) or CONTact surface may be specified.
Contact surface is equivalent to Accessible surface if a zero probe
radius is used. If the accuracy is not specified (or set to zero), then
the analytic result is provided. If a nonzero accuracy is provided,
then the original Lee and Richard's (points on a sphere) algorithm
is used.
------------------------------------------------------------------------------
14) The HELIX command
The COOR HELIx command will analyze a single helix, or the relative
orientation of two helicies. The use this command, one or two atom
selections should be provided selecting ONLY the atoms which will be
used to define the helix. The order of these atoms is important.
With a single atom selection, this command calculates the normalized
axis (A) and the perpendicular vector (R0) from the origin to A of
the cylinder most closely approximating a helix on which the selected
atoms best fit (Algorithm by J. Aqvist Computers & Chemistry
Vol. 10, pp97-99, (1986)).
With a double atom selection, this command also computes helix
axis and helix-helix structure analysis (Algorithm by Chotia, Levitt, and
Richardson JMB 145, P215-250 (1981)).
------------------------------------------------------------------------------
15) The CONVert command
The COOR CONVert command will cause the coordinates of all
defined and selected atoms to be transformed from the unit cell to
cartesian coordinates or back from cartesian to fractional coordinates.
Two orientations in cartesian coordinates are supported :
ALIGned - in which b-vector is along y-axis and a-vector
in xy-plane (this is old charmm standard)
SYMMetric - in which shape matrix constructed from unit
cell vectors is symmetric
Two keywords in any order [FRAC|ALIG|SYMM] are required after CONVert.
Unit cell parameters (a,b,c,alpha,beta,gamma) follow in the same line.
The angle values are specified in degrees. See the routine CONCOR for
details concerning the transformation.
------------------------------------------------------------------------------
16) The COVAriance command
The covarience command under coordinate manipulations
computes covariances of the spatial atom displacements of
a dynamics trajectory for selected pairs of atoms.
mu = E[ (R - E[R ]) (R - E[R ] )
JK J J K K
= E[R R ] - E[R ] E[R ]
J K J K
and the normalized covariance matrix is given by
CO = mu / SQRT(mu mu )
JK JK JJ KK
The command syntax and varibles are as in the coor dynamics command.
The exceptions are the keywords:
SET1: specifies the selection for the "J" groups in covarience
SET2: specifies the selection for the "K" groups in covarience
UNIT_for_output: specifies unit for output of covarience matrix (ascii)
DISTance_matrix: keyword specifying that trajectory of distance
matrix will be output in binary format to unit
specified by UNIT
RESIdue_average: is a logical for computing the average over
residues in SET2 specification. When followed by
NSETS: equal to 2 the average is over both SET1 and SET2
giving a NRES1 x NRES2 covarience matrix.
------------------------------------------------------------------------------
17) The ANALysis command
A "new" analysis module for computing solvent averaged properties
has been added to CHARMM. It is accessed from the coordinate manipulation
part (CORMAN) of CHARMM and is used with the following syntax. This
piece of documentation is still under development. CLBIII 1/1/1990
Keywords:
SOLVent: specifies analysis is to be of pure solvent, which means xref, yref
and zref, or site keywords are inappropriate, i.e., analysis all configurations
of solvent using all solvent molecules.
WATEr: specifies the solvent is water, and forces all distinct g(r)'s to be
computed, i.e., g_oo, g_oh and g_hh.
SPECies: specifies the solvent species. If SOLVent is active then all
solvent molecules to be analyzed should be specified here, e.g., all of them
present in the simulations. This keyword is followed by the standard selection
syntax and is terminated with the FINIsh_solvent_specification keyword.
SITE: Specifies the collection of atoms around which you would like to compute
solvent properties, e.g., if you would like to analyze the solvent distribution
and velocity correlation function around the center of geometry of a trp
residue this keyword would be followed by the selection syntax which selects
that residue.
XREF, YREF, ZREF: specifies that solvent analysis around a specific spatial
position, (xref, yref, zref) is to be carried out. This is the same as the
site keyword, as far as the analysis of solvent configurations it invokes,
however, this site is static whereas the SITE keyword permits selection of a
dynamically evolving site.
CROSs: allows the selection of two subset of atoms for g(r) analysis
(a&b). The g(r) for a-vs-b and b-vs-b are calculated and retuned in
units 9 and 10 respectively. if SOLVent is specified before CROSs,
g(r) for a-vs-a will be returned in unit 8. The keyword FINI must
follow the selection statments.
Note that CROSs does not exclude form the analysis the couple of atoms
belonging to the same segid since it is design for the analysis of
independent subset of solvent molecules.
The keyword CROSs cannot be selected with the following options:
WATer, SITE, IKIRkg, ISDIst, IFDBf.
IVAC, IMSD, IFMIn were not tested with CROSs.
Other keywords controlling calculations:
C NFIRST = number of first dynamics step to be read
C NSTEP = number of last dynamics step to be read
C NSKIP = number of dynamics steps to skip between calculations
C NCORS = number of steps to compute vac or msd
C RSPIN = inner radius for vac,msd, analysis around REF
C RSOUT = outer radius for vac,msd, analysis around REF
C DTVE = timestep for velocities (NSAVV*dynamics timestep)
C DTCO = timestep for coordinates (NSAVC*dynamics timestep)
C RDSP = radius of dynamics sphere, used for densities and dbf
C DR = grid spacing for analysis of rdf's
C RRSPHER = radius for rdf analysis
C MGN = number of points in g(r) curve
C IFDBF = 1 (0) do (don't do) deformable boundary force calculation
C RCUT = radius of interaction sphere in dbf calculation
C ZP0 = initial reference site - dynamics sphere origin separation
C NZP = number of separations to compute dbf
C for the following flags the presence of the keyword indicates
C that the flag is on (1). I.e., just put the flag keyword on the command line.
C IVAC = 1 (0) do (don't do) vac analysis
C IGDIST = 1 (0) do (don't do) solvent-solvent rdf analysis
C ISDIST = 1 (0) do (don't do) solvent-site rdf analysis
C IMSD = 1 (0) do (don't do) msd analysis
C IKIRKG = 1 (0) do (don't do) dipole analysis for water solvent
C IFMIN = 1 (0) periodic boundaries are (aren't) in effect
C XBOX = dimension of simulation box in x direction
C YBOX = dimension of simulation box in y direction
C ZBOX = dimension of simulation box in z direction
C ***********Current restrictions************************************
C ** Note IVAC and IMSD are mutually exclusive flags **
C ** Note IGDIST and ISDIST are mutually exclusive flags **
C *********** Unit usage ********************************************
C The coordinates are read from CHARMM dynamics output on file 20-29
C The velocities are read from CHARMM dynamics output on file 30-39
C The output is:
C fortran unit 7 is the vac in plt2 format
C fortran unit 8-10 solvent-solvent g(r)'s in plt2 format
C fortran unit 11 is the msd in plt2 format
C fortran unit 12 is the density profile in plt2 format
C fortran unit 13 is the dipole profile in plt2 format
C fortran unit 14 is the solvent-site g(r) in plt2 format
C fortran unit 15 is the time dependent dbf (see SUBROUTINE FBOUND for
C for details.
C fortran unit 16 is the averaged deformable boundary force in plt2
C format
C functions are also printed onto fortran unit 6 as output.
C
------------------------------------------------------------------------------
18) The DRAW command
The DRAW command (called directly from CORMAN, not to be
confused with the DRAW command found under the ANALysis command)
is useful for displaying molecules. The output is a command
file that can be read by various displaying and plotting programs.
This command file can be edited for different types of displaying.
In addition to atom positions and bonds, velocity and forces may
also be displayed. The current keywords are:
NOMO - No molecule option (only velocities or derivatives)
DFACt - Derivative factor (default 0.0)
DASH - Spacing of dashed line used for Hbonds (default .01)
FRAMe - Specifies that a frame tag will be written first
(default - dont specify frame)
RETUrn- Specifies which stream the plotting program will
return to after plotting this section (default none)
An atom selection is also looked for. Any atom not selected will
not be considered. The default is to include all atoms.
------------------------------------------------------------------------------
19) The HBONd command
The HBONd command analyses a trajectory for hydrogen bonding
patterns. For each acceptor/donor in the first selection the average
number and average lifetime of hydrogen bonds to any atom in the second
selection is calculated. A hydrogen bond is assumed to exist when two
candidate atoms are closer than the value specified by CUT (default 2.4A,
(reasonable criterion, DeLoof et al (1992) JACS 114,4028), and if a value
for CUTAngle is given the angle formed by D-H..A is greater than this CUTAngle
(in degrees, 180 is a linear H-bond); the default is to allow all angles.
The current implementation assumes that hbonding hydrogens are present in
the PSF and also uses ACCEptor and DONOr information from the PSF to determine
what pairs are possible. If output is wanted to a separate file the IUNIt
option can be used. If the BRIDge option is used the routine calculates average
number and lifetime of bridges formed between all pairs of atoms in the
two selections; a bridge is counted a residue of the type specicified with
the BRIDge <resnam> hydrogen bonds (using same criteria
as for direct hbonding) to at least one atom in each selection. The typical
use of this would be to find water bridges. Here again, results are presented
for each atom in the first selection.
NOTE: In order not to find hbonds between bonded atoms UPDATE is called,
which requires coordinates to be present when invoking this module. Since
this is done just to get the non-bond exclusion lists, the cut-offs are
set to very small values, and could influence subsequent energy evaluations
if the non-bond cutoffs are not then respecified.
Coordinate Manipulation Values
There are several different variables that can be used in titles or
CHARMM commands that are set by some of the coordinate manipulation commands.
Here is a summary and description of each variable.
----------------------------------------------------------------------------
'XAXI','YAXI','ZAXI','RAXI','XCEN','YCEN','ZCEN'
A rotation axis vector and its length and the center of rotation.
This data is set by the COOR AXIS, COOR ORIE, and COOR ORIE RMS commands.
These values may be used by any of the commands that uses the vector-spec
with the AXIS keyword.
----------------------------------------------------------------------------
'XMIN','YMIN','ZMIN','WMIN','XMAX','YMAX',
'ZMAX','WMAX','XAVE','YAVE','ZAVE','WAVE'
Statistics set by the COOR STAT command.
----------------------------------------------------------------------------
'THET'
Angle of rotation set by the COOR ORIEnt command.
----------------------------------------------------------------------------
'XMOV','YMOV','ZMOV'
Displacement of centers set by the COOR ORIEnt command.
----------------------------------------------------------------------------
'RMS'
Resulting RMS value set by the COOR RMS, COOR ORIEnt, or COOR RGYR
commands.
NIH/DCRT/Laboratory for Structural Biology
FDA/CBER/OVRR Biophysics Laboratory